[bengt]

I am using the following cmd file to do some backups of users files etc, but I would like to make it better and need help with that.
At the moment it works just fine but as it is now, if I would like to do another backup a day later or so, it will overwrite the previous, so here comes the obvious...

How do I change it so it will add a date or consecutive number to the following Backup folders?
Like, Backup1, Backup2, etc or Backup(date), Backup(next date)

abbreviated cmd-file

  @echo off
        :: variables
        set drive=C:\Backup
        set backupcmd=xcopy /s /c /d /e /h /i /r /y

        echo ### Backing up My Documents...
        %backupcmd% "%USERPROFILE%\My Documents" "%drive%\My Documents"

        echo ### Backing up Favorites...
        %backupcmd% "%USERPROFILE%\Favorites" "%drive%\Favorites"

        echo ### Backing up email and address book (Outlook Express)...
        %backupcmd% "%USERPROFILE%\Application Data\Microsoft\Address Book" "%drive%\Address Book"
        %backupcmd% "%USERPROFILE%\Local Settings\Application Data\Identities" "%drive%\Outlook Express"

        echo ### Backing up email and contacts (MS Outlook)...
        %backupcmd% "%USERPROFILE%\Local Settings\Application Data\Microsoft\Outlook" "%drive%\Outlook"

        echo ### Backing up the Registry...
        if not exist "%drive%\Registry" mkdir "%drive%\Registry"
        if exist "%drive%\Registry\regbackup.reg" del "%drive%\Registry\regbackup.reg"
        regedit /e "%drive%\Registry\regbackup.reg"

        echo Backup Complete!
        @pause

[bengt]

Doing this now...

@echo off

set drive=C:\Backup
set backupcmd=xcopy /s /c /d /e /h /i /r /y

::Grabbing date variables...

@For /F "tokens=1 delims=/ " %%A in ('Date /t') do set DD=%%A
@For /F "tokens=2 delims=/ " %%B in ('Date /t') do set MM=%%B
@For /F "tokens=3 delims=/ " %%C in ('Date /t') do set YY=%%C

Set CUSTOMDATE=-%DD%%MM%%YY%

echo ### Backing up My Documents...
%backupcmd% "%USERPROFILE%\My Documents" "%drive%%CUSTOMDATE%\My Documents"

echo ### Backing up Favorites...
%backupcmd% "%USERPROFILE%\Favorites" "%drive%%CUSTOMDATE%\Favorites"

echo ### Backing up email and address book (Outlook Express)...
%backupcmd% "%USERPROFILE%\Application Data\Microsoft\Address Book" "%drive%%CUSTOMDATE%\Address Book"
%backupcmd% "%USERPROFILE%\Local Settings\Application Data\Identities" "%drive%%CUSTOMDATE%\Outlook Express"

echo ### Backing up email and contacts (MS Outlook)...
%backupcmd% "%USERPROFILE%\Local Settings\Application Data\Microsoft\Outlook" "%drive%%CUSTOMDATE%\Outlook"

echo ### Backing up the Registry...
if not exist "%drive%%CUSTOMDATE%\Registry" mkdir "%drive%%CUSTOMDATE%\Registry"
if exist "%drive%%CUSTOMDATE%\Registry\regbackup.reg" del "%drive%%CUSTOMDATE%\Registry\regbackup.reg"
regedit /e "%drive%%CUSTOMDATE%\Registry\regbackup.reg"

echo Backup Complete!
@pause

[chuckr_jcr]

You might want to consider:

Set CUSTOMDATE=_%YY%%MM%%DD%

Quote

"Stop bothering me with stupid requests for plugins you silly retards can do on your own, alright?"

This post has been edited by chuckr_jcr: 03 June 2009 - 10:08 PM