I have been using the UBCD for a few months now and over the past few weeks have used the instructions on this thread to get it booting from a USB Flash Drive. Great job Dummptyhummty on putting this together.
masterchi, on Nov 28 2007, 09:57 AM, said:
**EDIT**I haven't looked at fixing it yet but it would be best to change the font color on the boot menu to black if possible, the white font on the UBCD4Win background makes it a bit hard to read.**
I am also interested in changing the font to be more legible on the boot menu. Has there been any developments on getting this changed? I suppose I could try to find a different background that makes the text more readable and then put that in the syslinux folder, but I am curious to know where the settings for the background and font color are.
----------------
Also, I have been working on batch files that automate much of the tasks for updating the Flash drive once you have created a new build. I work in an IT department and our techs find this tool incredibly useful. I have been the one updating and maintaining the UBCD, but we found it annoying to burn a new CD every time I wanted to update the anti-virus definitions or include a new tool. I wanted to make it very simple for our techs to update their flash drives to the latest build without having to do all the little tweaks each time. It's pretty simple, but basically I have it to the point where I use the UBCD4Win builder and then run a batch file that copies all the files needed to a network share (drive letter s: in the code examples below) and makes all the little tweaks to the BartPE folder that are necessary. Then the user (one of our techs) just has to run a batch file from our network share that will prompt for the drive letter of the Flash drive, erase the drive (with a prompt of course), reload the latest files from BartPE, run Syslinux, copy over the Boot Menu Files, and clean out the unneeded directories and files from the root of the drive. They still use PeToUSB the first time to get the drive bootable and formatted to fat16, but every time after that they just have to run the batch file. They are still a work in progress but I thought I would post them in case anyone was interested. Let me know what you think and if you have any suggestions:
Updating Network Share with the Latest BartPE files:
@echo off
cls
:_EraseBartPE
echo Erasing old BartPE:
echo -------------------
s:
cd "its\Ultimate Boot CD\USB Drive"
rmdir /s /q BartPE
:_CopyBartPE
echo Copying BartPE to S: Drive:
echo ----------------------------
xcopy c:\UBCD4Win\BartPE\* BartPE\ /H /E /Y
echo.
:_SetupBootFiles
echo Setting up Boot Files:
echo ----------------------
cd "BartPE"
xcopy i386\setupldr.bin
rename setupldr.bin ntldr
xcopy i386\ntdetect.com
rename i386 minint
:_End
echo Operation Completed!
pause
Update USB Flash Drive Batch File:
@echo off
:_SelectUSBdrive
set /p USBdrive=Enter your USB Flash drive (example e:):
cls
:_ConfirmErase
color 4f
echo **WARNING**
echo.
echo This batch file will erase the entire contents of drive %USBdrive%
echo and then copy the latest Ultimate Boot CD files.
echo.
set /p EraseChoice=Are you sure you want to erase drive %USBdrive% [y/n]?
IF %EraseChoice%==y GOTO _EraseUSBFlash ELSE GOTO _End
:_EraseUSBFlash
cls
color 07
IF EXIST %USBdrive%\Windows GOTO _ErrorWin
echo Erasing USB Flash Drive:
echo ------------------------
rmdir /s /q %USBdrive%\
:_CopyBartPE
echo Copying BartPE to USB Drive:
echo ----------------------------
cd BartPE
xcopy * %USBdrive% /H /E /Y
echo.
:_RunSyslinux
echo Running syslinux:
echo -----------------
cd "..\syslinux-3.61\win32"
syslinux %USBdrive%
echo.
:_CopyBootMenu
echo Coping Boot Menu Files:
echo -----------------------
cd ..\..\bootmenufiles
xcopy * %USBdrive% /H /E /Y
echo.
:_CleanUpDir
echo Removing unneeded Directories and Files:
echo ---------------------------------------
%USBdrive%
IF EXIST BCDW (rmdir /s /q BCDW) ELSE echo BCDW does not exist.
IF EXIST isolinux (rmdir /s /q isolinux) ELSE echo isolinux does not exist.
IF EXIST Images (rmdir /s /q images) ELSE echo images does not exist.
IF EXIST etc (del /q etc) ELSE echo etc does not exist.
IF EXIST bootsect.bin (del /q bootsect.bin) ELSE echo bootsect.bin does not exist.
IF EXIST Win51ip.sp2 (del /q win51ip.sp2) ELSE echo win51ip.sp2 does not exist.
IF EXIST win51ip (del /q win51ip) ELSE echo win51ip does not exist.
s:
echo.
echo Operation Completed!
pause
GOTO _End
:_ErrorWin
color 4f
echo Error: Drive %USBdrive% has a Windows directory. Aborting drive erase!
pause
:_End
color
Obviously if you want to use this, you will have to replace the paths to work with your own network shares.
Also, this is my first post (on any forum) so I apologize if I should post this somewhere else or something like that.
Sign In
Register
Help
MultiQuote
Posted 17 February 2008 - 08:25 PM
